у = x'∙sin(α) + x'∙cos(α),
где x' и y' — старые координаты точки, x и y — новые координаты точки, а α — угол поворота. Единственная загвоздка состоит в том, что функций sin и cos в базовой библиотеке XPath нет.
Самым простым выходом в такой ситуации является использование расширений. Например, в случае XSLT-процессора, который может использовать Java-расширения (Saxon, Xalan, Oracle XSLT Processor и так далее) надо будет лишь только объявить пространство имен вида:
xmlns:math="java:java.lang.Math"
и использовать функции math:sin и math:cos.
Листинг 10.6. Преобразование, осуществляющее поворот
<?xml version="1.0" encoding="windows-1251"?>
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.w3.org/2000/svg"
xmlns:math="java:java.lang.Math">
<xsl:output
indent="yes"
doctype-public="-//W3C//DTD SVG 1.0//EN"
doctype-system="http://www.w3.org/TR/2001/REC-SVG-20010904/DTD/svg10.dtd"/>
<xsl:param name="alpha" select="30"/>
<xsl:variable name="alpha-radian" select="3.14 * ($alpha div 180)"/>
<xsl:template match="/">
<svg width="200" height="200">
<desc>Simple line-based figure</desc>
<xsl:apply-templates select="точки"/>
</svg>
</xsl:template>
<xsl:template match="точки">
<g style="stroke:black; stroke-width:2">
<xsl:apply-templates select="точка"/>
</g>
</xsl:template>
<xsl:template match="точка">
<xsl:variable name="x1" select="@x"/>
<xsl:variable name="y1" select="@y"/>
<xsl:variable name="x2r">
<xsl:choose>
<xsl:when test="position() = last()">
<xsl:value-of select="preceding-sibling::точка[last()]/@x"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="following-sibling::точка[1]/@x"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="y2r">
<xsl:choose>
<xsl:when test="position() = last()">
<xsl:value-of select="preceding-sibling::точка[last()]/@y"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="following-sibling::точка[1]/@y"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="x2" select="number($x2r)"/>
<xsl:variable name="y2" select="number($y2r)"/>
<line
x1="{$x1 * math:cos($alpha-radian) -
$y1 * math:sin($alpha-radian) + 100}"
y1="{$x1 * math:sin($alpha-radian) +
$y1 * math:cos($alpha-radian) + 100}"
x2="{$x2 * math:cos($alpha-radian) -
$y2 * math:sin($alpha-radian) + 100}"
y2="{$x2 * math:sin($alpha-radian) +
$y2 * math:cos($alpha-radian) + 100}"/>
</xsl:template>
</xsl:stylesheet>
Результатом этого преобразования будет следующий документ.
Листинг 10.7. Результирующий SVG-документ
<!DOCTYPE svg
PUBLIC "-//W3C//DTD SVG 1.0//EN"
"http://www.w3.org/TR/2001/REC-SVG-20010904/DTD/svg10.dtd">
<svg
xmlns="http://www.w3.org/2000/svg"
xmlns:math="java:java.lang.Math"
width="200"
height="200">
<desc>Simple line-based figure</desc>
<g style="stroke:black; stroke-width:2">
<line
x1="81.68060041188197" y1="31.70359014757173"
x2="168.29640985242827" y2="81.68060041188197"/>
<line
x1="168.29640985242827" y1="81.68060041188197"
x2="118.31939958811803" y2="168.29640985242827"/>
<line
x1="118.31939958811803" y1="168.29640985242827"
x2="31.70359014757173" y2="118.31939958811803"/>
<line
x1="31.70359014757173" y1="118.31939958811803"
x2="81.68060041188197" y2="31.70359014757173"/>
</g>
</svg>
Визуальное представление этого документа демонстрирует рис. 10.2, где представлен поворот, выполненный на 30°:
Рис. 10.2. Визуальное представление полученного SVG-документа
Анализируя полученный документ, мы можем заметить объявление пространства имен с префиксом math, которое было в него включено:
<svg
xmlns="http://www.w3.org/2000/svg"
xmlns:math="java:java.lang.Math"
width="200"
height="200">
...
Это тот самый случай, когда объявление пространства имен используется в самом преобразовании, но является лишним в выходящем документе. Для того чтобы избавиться от него, нужно просто включить префикс math в атрибут exclude-result-prefixes элемента xsl:stylesheet.
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.w3.org/2000/svg"
xmlns:math="java:java.lang.Math"
exclude-result-prefixes="math">
...
Поскольку мы все равно используем в этом преобразовании расширения, мы можем написать свой собственный класс, который будет выполнять вычисление новых координат точки, исключив таким образом из преобразования все математические операции.
Листинг 10.8. Класс, вычисляющий координаты точки после поворота
package de.fzi.xslt;
public class rot {
public static double X(double x, double y, double degree) {
double radian = Math.PI * degree / 180;
return x * Math.cos(radian) - y * Math.sin(radian);
}
public static double Y(double x, double y, double degree) {
double radian = Math.PI * degree / 180;
return x * Math.sin(radian) + y * Math.cos(radian);
}
}
Для того чтобы использовать методы этого класса в качестве функций расширения, немного изменим объявления в элементе xsl:stylesheet:
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.w3.org/2000/svg"
xmlns:rot="java:de.fzi.xslt.rot"
exclude-result-prefixes="rot">
Создание элемента line теперь может быть записано в виде:
<line
x1="{rot:X($x1, $y1, $alpha) + 100}"
y1="{rot:Y($x1, $y1, $alpha) + 100}"
x2="{rot:X($x2, $y2, $alpha) + 100}"
y2="{rot:Y($x2, $y2, $alpha) + 100}"/>
Как мы отмечали выше, интерфейсы использования функций расширения весьма различаются между разными процессорами даже в случае такого переносимого языка, как Java. Отличия могут быть и в форме вызовов функций, и в форме объявлений пространств имен. Например, в процессоре Saxon пространство имен для класса de.fzi.xslt.rot может быть объявлено как:
xmlns:rot="java:de.fzi.xslt.rot"
в Xalan — как:
xmlns:rot="xalan://de.fzi.xslt.rot"
в Oracle XSLT Processor — как:
xmlns:rot="http://www.oracle.com/XSL/Transform/java/de.fzi.xslt.rot"
При этом сами вызовы во всех трех случаях будут одинаковыми:
rot:X($x, $y, $angle)
для метода X или
rot:Y($x, $y, $angle)
для метода Y.
Функция function-available
При использовании функций расширения всегда есть вероятность того, что это расширение в силу каких-либо причин поддерживаться данным процессором не будет. Чаще всего это случается, во-первых, когда процессор просто физически не в состоянии вызвать эту функцию (например, процессор, написанный на C++, вряд ли будет содержать средства для выполнения Java-кода), во-вторых, когда расширение недоступно (например, процессор не в состоянии найти указанный Java-класс или динамическую библиотеку), и в-третьих, когда пространство имен объявлено неверно (например, с URI java:de.fzi.xslt.rot вместо xalan://de.fzi.xslt.rot). Результатом обращения к неподдерживаемому расширению будет, естественно, ошибка.
XSLT позволяет избежать подобного рода ошибок путем предварительной проверки наличия заданной функции расширения. Для этой цели служит стандартная функция function-available (от англ. function is available — функция доступна)
boolean function-available(string)
Функция function-available принимает на вход строку, представляющую имя функции и возвращает true, если эта функция может быть вызвана и false — если нет.
Строковый аргумент этой функции представляет расширенное имя функции, он должен соответствовать продукции QName, то есть иметь вид имя или префикс:имя. В первом случае function-available проверяет, реализована ли в данном процессоре стандартная функция с таким именем, например function-available('concat') скорее всего, возвратит true.
В случае, если аргумент function-available имеет вид префикс:имя, функция function-available проверяет доступность указанной функции расширения. Например, для того, чтобы проверить, может ли в данном контексте быть вызвана функция rot:X, необходимо вычислить выражение
function-available('rot:X')
